Содержание Назад Вперед

Контурное представление поверхности

#
# $Id: contours.dem%v 3.38.2.146 1993/06/30 21:24:08 woo Exp woo $
#
set samples 20
set isosamples 21
set xlabel "X axis" -5,-2
set ylabel "Y axis" 4,-1
set zlabel "Z axis"
set title "3D gnu plot demo - contour plot"
set contour
splot x*y

set cntrparam levels 20
set title "3D gnu plot demo - contour plot (more contours)"
replot

set cntrparam levels incr -100,10,100
set title "3D gnu plot demo - contour plot (every 10, starting at -100)"
replot

set cntrparam levels disc -75,-50,0
set title "3D gnu plot demo - contour plot (at -75, -50, 0)"
replot

set cntrparam levels auto 10
set title "3D gnu plot demo - contour plot on base grid"
set contour base
splot x**2-y**2

set title "3D gnu plot demo - contour plot on surface"
set contour surface
replot

set title "3D gnu plot demo - contour plot on both"
set contour both
replot

set contour base
set title "3D gnu plot demo - 2 surfaces
splot x**2*y**3, x**3*y**2

set title "3D gnu plot demo - some more interesting contours"
splot x*y / (x**2 + y**2 + 0.1)

splot [x=-3:3] [y=-3:3] sin(x) * cos(y)

set zrange [-0.5:0.5]
replot

set samples 6
set isosamples 6
set cntrparam levels 5
set title "3D gnu plot demo - low resolution (6x6)"
replot

set cntrparam bspline
set title "3D gnu plot demo - low resolution (6x6) using bspline approx."
replot

set cntrparam order 8
set title "3D gnu plot demo - low resolution (6x6) raise bspline order."
replot

set cntrparam linear
set auto
set title "3D gnu plot demo - low resolution (6x6) using linear contours."
splot x*y

set cntrparam order 4
set cntrparam bspline
set title "3D gnu plot demo - low resolution (6x6) using bspline approx."
replot

set samples 25
set isosamples 26
set title "3D gnu plot demo - contour of Sinc function"
splot [-5:5.01] [-5:5.01] sin(sqrt(x**2+y**2)) / sqrt(x**2+y**2)

splot [-12:12.01] [-12:12.01] sin(sqrt(x**2+y**2)) / sqrt(x**2+y**2)

set cntrparam levels 10
set xrange [0:15]
set yrange [0:15]
set auto
set zrange [-0.6:0.6]
set data style lines
set title "3D gnu plot demo - contour of data grid plotting"
set parametric
splot "glass.dat"

set zrange [-1.2:1.2]
set noparametric
splot "glass.dat" using 1

set view 0,0,1
set nosurface
set title "3D gnu plot demo - 2D contour projection of last plot"
replot

#От: shen@athena.cs.uga.edu (Mingzuo Shen)
#Тема: функция Розенброка: некоторые ответы
#Дата: Wed, 23 Jun 1993 20:50:36 GMT
#
#    Вчера вечером я просил помощи с построение контура функции:
#
#    (1-x)**2 + 100 * (y - x**2)**2
#
#которая имеет минимум в точке (x=1,y=1). Это 2-ой случай 
#более общей функции Розенброка (в книге, которую я читаю нет
#каких-либо ссылок/книга этого автора):
#
#    даже для целого n,
#
#    f(x) = \sum_{j=1,3,5,\ldots,n} [(1 - x_j)^2 + 100(x_{j+1} - x_j^2)^2]
#
#где x - вектор (x1, x2, ..., x_n). Эта функция также имеет минимум
#в точке (1,1,...,1), который находится в основании "banana-shaped valley".
#Ниже новые команды, которые я пробовал.
#
set auto
set surface
set nocontour
set cntrparam levels 5
set cntrparam linear
set samples 100
set logscale z
set hidden3d
set isosamples 20
set view 70,335,1
set xlabel "x"
set ylabel "y"
set title "Rosenbrock Function"
splot [0.9:1.1] [0.9:1.1] (1-x)**2 + 100*(y - x**2)**2

set logscale z
set hidden3d
set isosamples 60
set view 20,340,1,2
set xlabel "x"
set ylabel "y"
splot [-1.5:1.5] [-0.5:1.5] (1-x)**2 + 100*(y - x**2)**2

set contour
set nosurface
replot

#
# Очистка:
#
set nolog
set surface
set nocontour
set cntrparam levels 5
set cntrparam linear
set samples 100
set isosamples 10
set view 60,30,1,1
set xrange [-10:10]
set yrange [-10:10]
set zrange [-10:10]
set auto
set title "" 0,0
set xlabel "" 0,0
set ylabel "" 0,0
set zlabel "" 0,0